Miller compensation and the right-half-plane zero

Two poles close together

OPA-B, the two-stage op-amp of E5.5, has two high-resistance nodes: o1, the first stage's output, and out. Each makes a pole at 1/(2πRC), above which the gain falls 20 dB per decade and the phase lags by up to 90°.

Watch C_c on the open-loop Bode plot of E5.5's bench, where 1 TH and 1 F close the loop for DC and open it for AC. For a buffer, the loop gain T is the op-amp's own gain.

C_c does two things at once, called pole splitting. The Miller effect (E6.1) makes it look like 97.7 pF at o1, which puts the first pole at 2.348 kHz by hand; the run says 2.292 kHz. And at high frequency it turns M6 into a diode, so the output pole rises to about g_m6/(2πC_L) = 31.3 MHz.

With one dominant pole, the gain reaches 1 at f_u ≈ g_m1/(2πC_c) = 26.2 MHz by hand (g_m1 = 164.5 µS). The run crosses at 20.8 MHz: the second pole sits close to f_u and pulls the gain down early.

The zero that lags

Follow the signal from o1 to out: M6 turns v_o1 into a current g_m6v_o1 that pulls out the opposite way. C_c carries jωC_cv_o1 across with the same sign as o1. Where ωC_c = g_m6 the two cancel: a zero at f_z = g_m6/(2πC_c).

A normal zero raises the gain and leads the phase. This one raises the gain and lags the phase, because the cancelling current has the opposite sign. It is a right-half-plane zero, named for where it sits in the complex s plane: it costs phase like a pole without the roll-off.

To see it alone, drive o1 from an AC source through 1 F; the rest of OPA-B keeps the bias.

Now the hook makes sense: doubling C_c lowers f_u to 12.5 MHz, but it also halves f_z to 31.3 MHz, on top of the output pole. Each costs atan(12.5/31.3) = 21.8°, so by hand PM ≈ 90° − 2 × 21.8° = 46.4°; the run measures 40.5°.

A resistor moves the zero

Put R_z in series with C_c and the zero moves to f_z = 1/(2πC_c(1/g_m6 − R_z)), so R_z = 1/g_m6 = 2.54 kΩ sends it to infinity. A larger R_z makes it negative: a left-half-plane zero, which adds phase near f_u.

More is not always better: at 15 kΩ the zero sits near 13 MHz and f_u runs out to 49.58 MHz. There the higher poles, including one that R_z adds with the capacitance at o1, cut the margin to 54.1°.

The hand design removes the zero and keeps the output pole at 2.2 f_u or above, which costs atan(1/2.2) = 24.4°. For OPA-B that gives C_c ≥ 2.2(g_m1/g_m6)C_L = 1.84 pF, with g_m read from the operating point. The run gives 61.2° at 12.72 MHz, against about 65° by hand.

RZ o1 z 0
CC z out 2p

RZ o1 z 5k
CC z out 1p

Try it

Run it and read fu and pm. rz_null is 1/g_m6, the R_z that cancels the zero. fz_hand is the zero from the formula: positive means the right half plane, negative the left. Open Plots to see the gain and phase.

Now fill a table. Set .param cc=1p rz=0, then rz=2.54k, then rz=10k, then cc=2p rz=0, and predict whether pm rises or falls before each run. Finally set cl=5p with cc=1p rz=5k: the output pole moves down, and E6.6 deals with that.

Check yourself

* OPA-B second stage driven at o1 through 1 F; C_c = 1 pF, R_z = 0, C_L = 2 pF
.lib sky130 tt
VDD vdd 0 1.8
IB vdd nb 20u
XMB nb nb 0 0 sky130_fd_pr__nfet_01v8 W=8 L=1
XM5 tail nb 0 0 sky130_fd_pr__nfet_01v8 W=8 L=1
XM1 x inn tail 0 sky130_fd_pr__nfet_01v8 W=10 L=1
XM2 o1 inp tail 0 sky130_fd_pr__nfet_01v8 W=10 L=1
XM3 x x vdd vdd sky130_fd_pr__pfet_01v8 W=8 L=1
XM4 o1 x vdd vdd sky130_fd_pr__pfet_01v8 W=8 L=1
XM6 out o1 vdd vdd sky130_fd_pr__pfet_01v8 W=32 L=1
XM7 out nb 0 0 sky130_fd_pr__nfet_01v8 W=16 L=1
RZ o1 z 0
CC z out 1p
CL out 0 2p
VIN inp 0 0.9
LF out inn 1T
CF inn 0 1
VAC ac 0 DC 0 AC 1
CD o1 ac 1
.control
ac dec 10 1k 1g
let h = v(out)/v(o1)
* +1 when the output moves with o1, -1 when it moves against it
let s = floor(real(h)/mag(h)+0.5)
meas ac sgn FIND s AT=1g
.endc
.end