Capstone: compensate a two-stage op-amp

The brief and the worst load

Your task is to compensate OPA-B, the two-stage op-amp of E5.5, as a buffer. The load is anywhere from 1 pF to 5 pF.

Start with the compensation of E6.4, C_c = 1 pF and R_z = 5 kΩ, and measure it at three loads. At 1 pF it has 75.3° at 25.29 MHz, at 2 pF 60.1° at 21.43 MHz, and at 5 pF only 41.4° at 15.25 MHz.

The reason is the output pole, p₂ ≈ g_m6/(2πC_L). With g_m6 = 393.4 µS it sits near 62.6 MHz at 1 pF and falls to 12.5 MHz at 5 pF, five times lower, while f_u falls only from 25.3 to 15.3 MHz. For a two-stage op-amp the heaviest load is the worst case.

A one-stage OTA behaves the other way. Its only high-resistance node is the output, so C_L sets its dominant pole (E5.3): more load lowers f_u and leaves more margin.

The textbook route and its price

The textbook method cancels the zero with R_z = 1/g_m6 and keeps p₂ at least 2.2 f_u at the worst load. At 5 pF that means f_u ≤ 12.5 MHz/2.2 = 5.7 MHz, below the brief. Measure it anyway: C_c = 4 pF with R_z = 2.54 kΩ gives 62.2° at 5.77 MHz. The hand estimate was right.

To raise p₂ you need more g_m6, which means more second-stage current. Widen M6 and M7 together by 2.5 times (80/1 and 40/1) so the offset rule of E5.5 still holds. Now g_m6 = 986.3 µS, so R_z = 1/g_m6 ≈ 1.01 kΩ, and C_c = 2 pF gives 61.4° at 11.62 MHz at 5 pF. The supply current rises from 79.54 µA to 141.3 µA: 254 µW instead of 143 µW.

There is a second way, with no extra current. E6.4 showed that R_z above 1/g_m6 turns the zero into a left-half-plane zero at 1/(2πC_c(R_z − 1/g_m6)), which adds phase. Put that zero near the 5 pF output pole and it cancels much of that pole's lag where it matters most.

The worked answer

With C_c = 1.75 pF and R_z = 8 kΩ the zero sits at 1/(2π·1.75 pF·5.46 kΩ) ≈ 16.7 MHz, just above the 5 pF output pole. The Bode plot shows the design at both ends of the load range. A margin above 90° at the light load means the phase of T at f_u is above −90°: the zero has given back more phase than the dominant pole took.

Both the power route and the zero route meet the brief. The zero route costs no current, but it depends on R_z against 1/g_m6. With R_z 20 % low (6.4 kΩ) the 5 pF margin falls to 64.9° at 11.63 MHz; 20 % high (9.6 kΩ) it is 77.2°. Both still pass.

It also settles more slowly at light loads. The power route reaches 1 % in 47.4 ns at 1 pF; the zero route takes 73.1 ns, because its zero and the closed-loop pole near it leave a slow tail. If the brief had a settling time, that would decide between them.

XM6 out o1 vdd vdd sky130_fd_pr__pfet_01v8 W=80 L=1
XM7 out nb 0 0 sky130_fd_pr__nfet_01v8 W=40 L=1
RZ o1 z 1.01k
CC z out 2p

XM6 out o1 vdd vdd sky130_fd_pr__pfet_01v8 W=32 L=1
XM7 out nb 0 0 sky130_fd_pr__nfet_01v8 W=16 L=1
RZ o1 z 8k
CC z out 1.75p

Try it

The starter is E6.4's compensation at the 5 pF corner of the brief. Run it: pm and overshoot both fail. Open Plots to see the loop gain and the step.

Now find your own answer. Change cc and rz, then run it again at cl=1p and cl=2p: a design passes only if it passes at every load. The worked answer is one solution, not the only one.

Check yourself

* OPA-B buffer, C_c = 1 pF and R_z = 5 kOhm, open loop at C_L = 1 pF and 5 pF
.lib sky130 tt
.subckt opab inp inn out vdd cc=1p rz=5k w6=32 w7=16
IB vdd nb 20u
XMB nb nb 0 0 sky130_fd_pr__nfet_01v8 W=8 L=1
XM5 tail nb 0 0 sky130_fd_pr__nfet_01v8 W=8 L=1
XM1 x inn tail 0 sky130_fd_pr__nfet_01v8 W=10 L=1
XM2 o1 inp tail 0 sky130_fd_pr__nfet_01v8 W=10 L=1
XM3 x x vdd vdd sky130_fd_pr__pfet_01v8 W=8 L=1
XM4 o1 x vdd vdd sky130_fd_pr__pfet_01v8 W=8 L=1
XM6 out o1 vdd vdd sky130_fd_pr__pfet_01v8 W={w6} L=1
XM7 out nb 0 0 sky130_fd_pr__nfet_01v8 W={w7} L=1
RZ o1 z {rz}
CC z out {cc}
.ends
VIN in 0 DC 0.9 AC 1
Va vda 0 1.8
Xa in ia oa vda opab cc=1p rz=5k
Ca oa 0 1p
La oa ia 1T
CFa ia 0 1
Vb vdb 0 1.8
Xb in ib ob vdb opab cc=1p rz=5k
Cb ob 0 5p
Lb ob ib 1T
CFb ib 0 1
.save v(oa) v(ob)
.control
ac dec 20 10k 1g
let one = 1+0*vdb(oa)
let ga = vdb(oa)
let gb = vdb(ob)
let pa = 180+180/pi*cph(v(oa))
let pb = 180+180/pi*cph(v(ob))
* step to the first point where each gain has fallen below 0 dB
let ka = 0
while ga[ka] gt 0
let ka = ka+1
end
let kb = 0
while gb[kb] gt 0
let kb = kb+1
end
* +1 if the margin rises from 1 pF to 5 pF, -1 if it falls
let d = pb[kb]-pa[ka]
let s = d/abs(d)*one
meas ac change FIND s AT=1meg
.endc
.end